cmake_minimum_required(VERSION 3.16)
project(microircd LANGUAGES C)

add_compile_definitions(UIRCD_VERSION="2020.12.30")

OPTION(CODE_ANALYZER "Analyze the code statically" ON)
OPTION(CODE_COVERAGE "Build with coverage tools" OFF)

if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
	add_compile_options(-Wall -Wextra -Werror -Wformat-overflow=2 -Wformat-security -Winit-self -Wstrict-overflow=2 -Wstringop-overflow=2 -Walloc-zero -Wduplicated-branches -Wduplicated-cond -Wtrampolines -Wfloat-equal -Wshadow -Wunsafe-loop-optimizations -Wparentheses -pedantic -fstack-check -Wno-unused-parameter)
	if ( CODE_ANALYZER )
		add_compile_options(-fanalyzer)
	endif()
elseif (CMAKE_C_COMPILER_ID STREQUAL "Clang")
	add_compile_options(-Weverything -Wno-padded -Wno-disabled-macro-expansion -pedantic)
	if ( CODE_COVERAGE )
		add_compile_options(-fprofile-instr-generate -fcoverage-mapping)
	endif()
endif()

add_executable(uircd
	src/buffer.c
	src/configuration.c
	src/connection.c
	src/filesystem.c
	src/logging.c
	src/main.c
	src/memory.c
	src/signal.c
	src/channels.c
)

find_library(UIRC_PATH NAMES uirc REQUIRED)
find_library(LIBCONFIG_PATH NAMES config)
if(NOT LIBCONFIG_PATH)
	message(WARNING "libconfig not found. uIRCd will not support configuration files")
else()
	message(STATUS "Building with libconfig support")
	add_compile_definitions(UIRCD_FEATURE_LIBCONFIG)
	target_link_libraries(uircd ${LIBCONFIG_PATH})
endif()
target_link_libraries(uircd ${UIRC_PATH})
set_property(TARGET uircd PROPERTY C_STANDARD 99)

install(TARGETS uircd RUNTIME)