mirror of
https://github.com/ceph/ceph
synced 2024-12-22 03:22:00 +00:00
a05d7179e2
in 0437adc33a, we stop right before
reaching $top_srcdir, but we should stop at its parent directory.
in this change, instead of trying to be smart and to walk all the way
up to the root directory or $top_srcdir, we just check $top_srcdir/.git
directly, as we just know it's there or it does not exist at all.
Signed-off-by: Kefu Chai <kchai@redhat.com>
129 lines
3.9 KiB
CMake
129 lines
3.9 KiB
CMake
# - Returns a version string from Git
|
|
#
|
|
# These functions force a re-configure on each git commit so that you can
|
|
# trust the values of the variables in your build system.
|
|
#
|
|
# get_git_head_revision(<refspecvar> <hashvar> [<additional arguments to git describe> ...])
|
|
#
|
|
# Returns the refspec and sha hash of the current head revision
|
|
#
|
|
# git_describe(<var> [<additional arguments to git describe> ...])
|
|
#
|
|
# Returns the results of git describe on the source tree, and adjusting
|
|
# the output so that it tests false if an error occurs.
|
|
#
|
|
# git_get_exact_tag(<var> [<additional arguments to git describe> ...])
|
|
#
|
|
# Returns the results of git describe --exact-match on the source tree,
|
|
# and adjusting the output so that it tests false if there was no exact
|
|
# matching tag.
|
|
#
|
|
# Requires CMake 2.6 or newer (uses the 'function' command)
|
|
#
|
|
# Original Author:
|
|
# 2009-2010 Ryan Pavlik <rpavlik@iastate.edu> <abiryan@ryand.net>
|
|
# http://academic.cleardefinition.com
|
|
# Iowa State University HCI Graduate Program/VRAC
|
|
#
|
|
# Copyright Iowa State University 2009-2010.
|
|
# Distributed under the Boost Software License, Version 1.0.
|
|
# (See accompanying file LICENSE_1_0.txt or copy at
|
|
# http://www.boost.org/LICENSE_1_0.txt)
|
|
|
|
if(__get_git_revision_description)
|
|
return()
|
|
endif()
|
|
set(__get_git_revision_description YES)
|
|
|
|
# We must run the following at "include" time, not at function call time,
|
|
# to find the path to this module rather than the path to a calling list file
|
|
get_filename_component(_gitdescmoddir ${CMAKE_CURRENT_LIST_FILE} PATH)
|
|
|
|
function(get_git_head_revision _refspecvar _hashvar)
|
|
set(GIT_DIR "${CMAKE_SOURCE_DIR}/.git")
|
|
if(NOT EXISTS "${GIT_DIR}") # .git dir not found
|
|
# We have reached the top of the source tree, we are not in git
|
|
set(${_refspecvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
|
|
set(${_hashvar} "GITDIR-NOTFOUND" PARENT_SCOPE)
|
|
return()
|
|
endif()
|
|
# check if this is a submodule or git-worktree
|
|
if(NOT IS_DIRECTORY ${GIT_DIR})
|
|
file(READ ${GIT_DIR} gitdirfile)
|
|
string(REGEX REPLACE "gitdir: (.*)\n$" "\\1" GIT_DIR_PATH ${gitdirfile})
|
|
if(IS_ABSOLUTE ${GIT_DIR_PATH})
|
|
get_filename_component(GIT_DIR ${GIT_DIR_PATH} ABSOLUTE)
|
|
else()
|
|
get_filename_component(LINKED_DIR ${GIT_DIR} PATH)
|
|
get_filename_component(GIT_DIR ${LINKED_DIR}/${GIT_DIR_PATH} ABSOLUTE)
|
|
endif()
|
|
endif()
|
|
set(GIT_DATA "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/git-data")
|
|
if(NOT EXISTS "${GIT_DATA}")
|
|
file(MAKE_DIRECTORY "${GIT_DATA}")
|
|
endif()
|
|
|
|
if(NOT EXISTS "${GIT_DIR}/HEAD")
|
|
return()
|
|
endif()
|
|
set(HEAD_FILE "${GIT_DATA}/HEAD")
|
|
configure_file("${GIT_DIR}/HEAD" "${HEAD_FILE}" COPYONLY)
|
|
|
|
configure_file("${_gitdescmoddir}/GetGitRevisionDescription.cmake.in"
|
|
"${GIT_DATA}/grabRef.cmake"
|
|
@ONLY)
|
|
include("${GIT_DATA}/grabRef.cmake")
|
|
|
|
set(${_refspecvar} "${HEAD_REF}" PARENT_SCOPE)
|
|
set(${_hashvar} "${HEAD_HASH}" PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(git_describe _var)
|
|
if(NOT GIT_FOUND)
|
|
find_package(Git QUIET)
|
|
endif()
|
|
get_git_head_revision(refspec hash)
|
|
if(NOT GIT_FOUND)
|
|
set(${_var} "GIT-NOTFOUND" PARENT_SCOPE)
|
|
return()
|
|
endif()
|
|
if(NOT hash)
|
|
set(${_var} "HEAD-HASH-NOTFOUND" PARENT_SCOPE)
|
|
return()
|
|
endif()
|
|
|
|
# TODO sanitize
|
|
#if((${ARGN}" MATCHES "&&") OR
|
|
# (ARGN MATCHES "||") OR
|
|
# (ARGN MATCHES "\\;"))
|
|
# message("Please report the following error to the project!")
|
|
# message(FATAL_ERROR "Looks like someone's doing something nefarious with git_describe! Passed arguments ${ARGN}")
|
|
#endif()
|
|
|
|
#message(STATUS "Arguments to execute_process: ${ARGN}")
|
|
|
|
execute_process(COMMAND
|
|
"${GIT_EXECUTABLE}"
|
|
describe
|
|
${hash}
|
|
${ARGN}
|
|
WORKING_DIRECTORY
|
|
"${CMAKE_CURRENT_SOURCE_DIR}"
|
|
RESULT_VARIABLE
|
|
res
|
|
OUTPUT_VARIABLE
|
|
out
|
|
ERROR_QUIET
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE)
|
|
if(NOT res EQUAL 0)
|
|
set(out "${out}-${res}-NOTFOUND")
|
|
endif()
|
|
|
|
set(${_var} "${out}" PARENT_SCOPE)
|
|
endfunction()
|
|
|
|
function(git_get_exact_tag _var)
|
|
git_describe(out --exact-match ${ARGN})
|
|
set(${_var} "${out}" PARENT_SCOPE)
|
|
endfunction()
|