mirror of
https://github.com/kdave/btrfs-progs
synced 2024-12-16 03:15:39 +00:00
eb7b42003a
GCC releases prior to 4.5.0 don't support -std=gnu90 so btrfs-progs won't build at all on older distros. We can detect whether the compiler supports -std=gnu90 and fall back to -std=gnu89 if it doesn't. AX_CHECK_COMPILE_FLAG is the right way to do this, but it depends on autoconf 2.64. AX_GCC_VERSION has been deprecated, so we'll use that only for earlier autoconf versions so we can drop it when we drop support for older autoconf releases. Signed-off-by: Jeff Mahoney <jeffm@suse.com> Signed-off-by: David Sterba <dsterba@suse.com>
38 lines
1.1 KiB
Plaintext
38 lines
1.1 KiB
Plaintext
dnl @synopsis AX_GCC_VERSION(MAJOR, MINOR, PATCHLEVEL, [ACTION-SUCCESS], [ACTION-FAILURE])
|
|
dnl @summary check wither gcc is at least version MAJOR.MINOR.PATCHLEVEL
|
|
dnl @category InstalledPackages
|
|
dnl
|
|
dnl Check whether we are using gcc and, if so, whether its version
|
|
dnl is at least MAJOR.MINOR.PATCHLEVEL
|
|
dnl
|
|
dnl ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
|
|
dnl success/failure.
|
|
dnl
|
|
dnl @version 2005-05-30
|
|
dnl @license GPLWithACException
|
|
dnl @author Steven G. Johnson <stevenj@alum.mit.edu> and Matteo Frigo.
|
|
AC_DEFUN([AX_GCC_VERSION],
|
|
[
|
|
AC_REQUIRE([AC_PROG_CC])
|
|
AC_CACHE_CHECK(whether we are using gcc $1.$2.$3 or later, ax_cv_gcc_$1_$2_$3,
|
|
[
|
|
ax_cv_gcc_$1_$2_$3=no
|
|
if test "$GCC" = "yes"; then
|
|
dnl The semicolon after "yes" below is to pacify NeXT's syntax-checking cpp.
|
|
AC_EGREP_CPP(yes, [
|
|
#ifdef __GNUC__
|
|
# if (__GNUC__ > $1) || (__GNUC__ == $1 && __GNUC_MINOR__ > $2) \
|
|
|| (__GNUC__ == $1 && __GNUC_MINOR__ == $2 && __GNUC_PATCHLEVEL__ >= $3)
|
|
yes;
|
|
# endif
|
|
#endif
|
|
], [ax_cv_gcc_$1_$2_$3=yes])
|
|
fi
|
|
])
|
|
if test "$ax_cv_gcc_$1_$2_$3" = yes; then
|
|
m4_default([$4], :)
|
|
else
|
|
m4_default([$5], :)
|
|
fi
|
|
])
|