mirror of
https://github.com/dense-analysis/ale
synced 2024-12-24 15:13:02 +00:00
a81512cfd2
Previously, it would not generate any lint messages for nix 2.5.
Moreover, it would cause this error whenever the nix command is
invoked, when paired with a custom `g:ale_command_wrapper`:
Error detected while processing function <SNR>92_NeoVimCallback[29]..<lambda>27[
1]..<SNR>90_ExitCallback[28]..ale_linters#nix#nix#Command:
line 1:
E684: list index out of range: 0
64 lines
1.8 KiB
VimL
64 lines
1.8 KiB
VimL
" Author: Alistair Bill <@alibabzo>
|
|
" Author: Maximilian Bosch <maximilian@mbosch.me>
|
|
" Description: nix-instantiate linter for nix files
|
|
|
|
function! ale_linters#nix#nix#Command(buffer, output, meta) abort
|
|
let l:version = a:output[0][22:]
|
|
|
|
if l:version =~# '^\(2.[4-9]\|3\).*'
|
|
return 'nix-instantiate --log-format internal-json --parse -'
|
|
else
|
|
return 'nix-instantiate --parse -'
|
|
endif
|
|
endfunction
|
|
|
|
function! ale_linters#nix#nix#Handle(buffer, lines) abort
|
|
let l:output = []
|
|
|
|
if empty(a:lines)
|
|
return l:output
|
|
endif
|
|
|
|
if a:lines[0] =~# '^@nix .*'
|
|
for l:line in a:lines
|
|
if l:line =~# '^@nix .*'
|
|
let l:result = json_decode(strpart(l:line, 4))
|
|
|
|
if has_key(l:result, 'column')
|
|
call add(l:output, {
|
|
\ 'type': 'E',
|
|
\ 'lnum': l:result.line,
|
|
\ 'col': l:result.column,
|
|
\ 'text': l:result.raw_msg
|
|
\})
|
|
endif
|
|
endif
|
|
endfor
|
|
else
|
|
let l:pattern = '^\(.\+\): \(.\+\) at .*:\(\d\+\):\(\d\+\)$'
|
|
|
|
for l:match in ale#util#GetMatches(a:lines, l:pattern)
|
|
call add(l:output, {
|
|
\ 'lnum': l:match[3] + 0,
|
|
\ 'col': l:match[4] + 0,
|
|
\ 'text': l:match[1] . ': ' . substitute(l:match[2], ',$', '', ''),
|
|
\ 'type': l:match[1] =~# '^error' ? 'E' : 'W',
|
|
\})
|
|
endfor
|
|
endif
|
|
|
|
return l:output
|
|
endfunction
|
|
|
|
call ale#linter#Define('nix', {
|
|
\ 'name': 'nix',
|
|
\ 'output_stream': 'stderr',
|
|
\ 'executable': 'nix-instantiate',
|
|
\ 'command': {buffer -> ale#command#Run(
|
|
\ buffer,
|
|
\ 'nix-instantiate --version',
|
|
\ function('ale_linters#nix#nix#Command')
|
|
\ )},
|
|
\ 'callback': 'ale_linters#nix#nix#Handle',
|
|
\})
|