Asynchronous Lint Engine

ALE (Asynchronous Lint Engine) is a plugin for providing linting in NeoVim and Vim 8 while you edit your text files.

ALE makes use of NeoVim and Vim 8 job control functions and timers to run linters on the contents of text buffers and return errors as text is changed in Vim. This allows for displaying warnings and errors in files being edited in Vim before files have been saved back to a filesystem.

In other words, this plugin allows you to lint while you type.

In addition to linting support, ALE offers some support for fixing code with formatting tools, and completion via Language Server Protocol servers, or servers with similar enough protocols, like tsserver.

Table of Contents

1. Supported Languages and Tools
2. Usage
   1. Linting
   2. Fixing
   3. Completion
3. Installation
   1. Installation with Vim package management
   2. Installation with Pathogen
   3. Installation with Vundle
4. Contributing
5. FAQ
   1. How do I disable particular linters?
   2. How can I keep the sign gutter open?
   3. How can I change the signs ALE uses?
   4. How can I show errors or warnings in my statusline?
   5. How can I show errors or warnings in my lightline?
   6. How can I change the format for echo messages?
   7. How can I execute some code when ALE stops linting?
   8. How can I navigate between errors quickly?
   9. How can I run linters only when I save files?
   10. How can I use the quickfix list instead of the loclist?
   11. How can I check JSX files with both stylelint and eslint?
   12. Will this plugin eat all of my laptop battery power?

1. Supported Languages and Tools

This plugin supports the following languages and tools. All available tools will be run in combination, so they can be complementary.

Notes:

• ^ No linters for text or Vim help filetypes are enabled by default.
• !! These linters check only files on disk. See :help ale-lint-file-linters

Language	Tools
ASM	gcc
Ansible	ansible-lint
AsciiDoc	proselint
Awk	gawk
Bash	shell -n flag, shellcheck
Bourne Shell	shell -n flag, shellcheck
C	cppcheck, cpplint, gcc, clang, clangtidy !!, clang-format
C++ (filetype cpp)	clang, clangcheck !!, clangtidy !!, cppcheck, cpplint !!, gcc, clang-format
CUDA	nvcc
C#	mcs see:help ale-cs-mcs for details, mcsc !! see:help ale-cs-mcsc for details and configuration
Chef	foodcritic
CMake	cmakelint
CoffeeScript	coffee, coffeelint
Crystal	crystal !!
CSS	csslint, stylelint, prettier
Cython (pyrex filetype)	cython
D	dmd
Dart	dartanalyzer
Dockerfile	hadolint
Elixir	credo, dogma !!
Elm	elm-format, elm-make
Erb	erb, erubis
Erlang	erlc, SyntaxErl
Fortran	gcc
FusionScript	fusion-lint
GLSL	glslang
Go	gofmt, go vet, golint, gometalinter !!, go build !!, gosimple, staticcheck
GraphQL	gqlint
Haml	haml-lint
Handlebars	ember-template-lint
Haskell	ghc, stack-ghc, stack-build !!, ghc-mod, stack-ghc-mod, hlint, hdevtools
HTML	HTMLHint, proselint, tidy
Idris	idris
Java	checkstyle, javac
JavaScript	eslint, jscs, jshint, flow, prettier, prettier-eslint >= 4.2.0, prettier-standard, standard, xo
JSON	jsonlint, prettier
Kotlin	kotlinc !!, ktlint !! see :help ale-integration-kotlin for configuration instructions
LaTeX	chktex, lacheck, proselint
LLVM	llc
Lua	luacheck
Markdown	mdl, proselint, vale, remark-lint !!
MATLAB	mlint
Nim	nim check !!
nix	nix-instantiate
nroff	proselint
Objective-C	clang
Objective-C++	clang
OCaml	merlin see :help ale-ocaml-merlin for configuration instructions
Perl	perl -c, perl-critic
PHP	hack, langserver, php -l, phpcs, phpmd, phpstan, phpcbf
Pod	proselint
Pug	pug-lint
Puppet	puppet, puppet-lint
Python	autopep8, flake8, isort, mypy, pycodestyle, pylint !!, yapf
R	lintr
ReasonML	merlin see :help ale-integration-reason-merlin for configuration instructions
reStructuredText	proselint
RPM spec	rpmlint (disabled by default; see :help ale-integration-spec)
Ruby	brakeman !!, rails_best_practices !!, reek, rubocop, ruby
Rust	cargo !! (see :help ale-integration-rust for configuration instructions), rls, rustc
SASS	sass-lint, stylelint
SCSS	sass-lint, scss-lint, stylelint, prettier
Scala	scalac, scalastyle
Slim	slim-lint
SML	smlnj
Solidity	solium
Stylus	stylelint
SQL	sqlint
Swift	swiftlint, swiftformat
Tcl	nagelfar !!
Texinfo	proselint
Text^	proselint, vale
Thrift	thrift
TypeScript	eslint, tslint, tsserver, typecheck, prettier
Verilog	iverilog, verilator
Vim	vint
Vim help^	proselint
XHTML	proselint
XML	xmllint
YAML	swaglint, yamllint

2. Usage

2.i Linting

Once this plugin is installed, while editing your files in supported languages and tools which have been correctly installed, this plugin will send the contents of your text buffers to a variety of programs for checking the syntax and semantics of your programs. By default, linters will be re-run in the background to check your syntax when you open new buffers or as you make edits to your files.

The behaviour of linting can be configured with a variety of options, documented in the Vim help file. For more information on the options ALE offers, consult :help ale-options for global options and :help ale-linter-options for options specified to particular linters.

2.ii Fixing

ALE can fix files with the ALEFix command. Functions need to be configured for different filetypes with the g:ale_fixers variable. For example, the following code can be used to fix JavaScript code with ESLint:

" Put this in vimrc or a plugin file of your own.
" After this is configured, :ALEFix will try and fix your JS code with ESLint.
let g:ale_fixers = {
\   'javascript': ['eslint'],
\}

" Set this setting in vimrc if you want to fix files automatically on save.
" This is off by default.
let g:ale_fix_on_save = 1

The :ALEFixSuggest command will suggest some supported tools for fixing code, but fixers can be also implemented with functions, including lambda functions too. See :help ale-fix for detailed information.

2.iii Completion

ALE offers some support for completion via hijacking of omnicompletion while you type. All of ALE's completion information must come from Language Server Protocol linters, or similar protocols. At the moment, completion is only supported for TypeScript code with tsserver, when tsserver is enabled. You can enable completion like so:

" Enable completion where available.
let g:ale_completion_enabled = 1

See :help ale-completion for more information.

3. Installation

To install this plugin, you should use one of the following methods. For Windows users, replace usage of the Unix ~/.vim directory with %USERPROFILE%\vimfiles, or another directory if you have configured Vim differently. On Windows, your ~/.vimrc file will be similarly stored in %USERPROFILE%\_vimrc.

3.i. Installation with Vim package management

In Vim 8 and NeoVim, you can install plugins easily without needing to use any other tools. Simply clone the plugin into your pack directory.

Vim 8 on Unix

mkdir -p ~/.vim/pack/git-plugins/start
git clone https://github.com/w0rp/ale.git ~/.vim/pack/git-plugins/start/ale

NeoVim on Unix

mkdir -p ~/.local/share/nvim/site/pack/git-plugins/start
git clone https://github.com/w0rp/ale.git ~/.local/share/nvim/site/pack/git-plugins/start/ale

Vim 8 on Windows

# Run these commands in the "Git for Windows" Bash terminal
mkdir -p ~/vimfiles/pack/git-plugins/start
git clone https://github.com/w0rp/ale.git ~/vimfiles/pack/git-plugins/start/ale

Generating Vim help files

You can add the following line to your vimrc files to generate documentation tags automatically, if you don't have something similar already, so you can use the :help command to consult ALE's online documentation:

" Put these lines at the very end of your vimrc file.

" Load all plugins now.
" Plugins need to be added to runtimepath before helptags can be generated.
packloadall
" Load all of the helptags now, after plugins have been loaded.
" All messages and errors will be ignored.
silent! helptags ALL

3.ii. Installation with Pathogen

To install this module with Pathogen, you should clone this repository to your bundle directory, and ensure you have the line execute pathogen#infect() in your ~/.vimrc file. You can run the following commands in your terminal to do so:

cd ~/.vim/bundle
git clone https://github.com/w0rp/ale.git

3.iii. Installation with Vundle

You can install this plugin using Vundle by using the path on GitHub for this repository.

Plugin 'w0rp/ale'

See the Vundle documentation for more information.

4. Contributing

If you would like to see support for more languages and tools, please create an issue or create a pull request. If your tool can read from stdin or you have code to suggest which is good, support can be happily added for it.

If you are interested in the general direction of the project, check out the wiki home page. The wiki includes a Roadmap for the future, and more.

If you'd liked to discuss the project more directly, check out the #vim-ale channel on Freenode. Web chat is available here.

5. FAQ

5.i. How do I disable particular linters?

By default, all available tools for all supported languages will be run. If you want to only select a subset of the tools, simply create a g:ale_linters dictionary in your vimrc file mapping filetypes to lists of linters to run.

let g:ale_linters = {
\   'javascript': ['eslint'],
\}

For all languages unspecified in the dictionary, all possible linters will be run for those languages, just as when the dictionary is not defined. Running many linters should not typically obstruct editing in Vim, as they will all be executed in separate processes simultaneously.

This plugin will look for linters in the ale_linters directory. Each directory within corresponds to a particular filetype in Vim, and each file in each directory corresponds to the name of a particular linter.

5.ii. How can I keep the sign gutter open?

You can keep the sign gutter open at all times by setting the g:ale_sign_column_always to 1

let g:ale_sign_column_always = 1

5.iii. How can I change the signs ALE uses?

Use these options to specify what text should be used for signs:

let g:ale_sign_error = '>>'
let g:ale_sign_warning = '--'

ALE sets some background colors automatically for warnings and errors in the sign gutter, with the names ALEErrorSign and ALEWarningSign. These colors can be customised, or even removed completely:

highlight clear ALEErrorSign
highlight clear ALEWarningSign

5.iv. How can I show errors or warnings in my statusline?

vim-airline integrates with ALE for displaying error information in the status bar. If you want to see the status for ALE in a nice format, it is recommended to use vim-airline with ALE. The airline extension can be enabled by adding the following to your vimrc:

" Set this. Airline will handle the rest.
let g:airline#extensions#ale#enabled = 1

If you don't want to use vim-airline, you can implement your own statusline function without adding any other plugins. ALE provides a function for counting the number of problems for this purpose, named ale#statusline#Count.

Say you want to display all errors as one figure, and all non-errors as another figure. You can do the following:

function! LinterStatus() abort
    let l:counts = ale#statusline#Count(bufnr(''))

    let l:all_errors = l:counts.error + l:counts.style_error
    let l:all_non_errors = l:counts.total - l:all_errors

    return l:counts.total == 0 ? 'OK' : printf(
    \   '%dW %dE',
    \   all_non_errors,
    \   all_errors
    \)
endfunction

set statusline=%{LinterStatus()}

See :help ale#statusline#Count() for more information.

5.v. How can I show errors or warnings in my lightline?

lightline does not have built-in support for ALE, nevertheless it's easy to do it yourself:

" This is regular lightline configuration, we just added
" 'linter_warnings', 'linter_errors' and 'linter_ok' to
" the active right panel. Feel free to move it anywhere.
" `component_expand' and `component_type' are required.
"
" For more info on how this works, see lightline documentation.
let g:lightline = {
      \ 'active': {
      \   'right': [ [ 'lineinfo' ],
      \              [ 'percent' ],
      \              [ 'linter_warnings', 'linter_errors', 'linter_ok' ],
      \              [ 'fileformat', 'fileencoding', 'filetype' ] ]
      \ },
      \ 'component_expand': {
      \   'linter_warnings': 'LightlineLinterWarnings',
      \   'linter_errors': 'LightlineLinterErrors',
      \   'linter_ok': 'LightlineLinterOK'
      \ },
      \ 'component_type': {
      \   'linter_warnings': 'warning',
      \   'linter_errors': 'error',
      \   'linter_ok': 'ok'
      \ },
      \ }

autocmd User ALELint call lightline#update()

" ale + lightline
function! LightlineLinterWarnings() abort
  let l:counts = ale#statusline#Count(bufnr(''))
  let l:all_errors = l:counts.error + l:counts.style_error
  let l:all_non_errors = l:counts.total - l:all_errors
  return l:counts.total == 0 ? '' : printf('%d --', all_non_errors)
endfunction

function! LightlineLinterErrors() abort
  let l:counts = ale#statusline#Count(bufnr(''))
  let l:all_errors = l:counts.error + l:counts.style_error
  let l:all_non_errors = l:counts.total - l:all_errors
  return l:counts.total == 0 ? '' : printf('%d >>', all_errors)
endfunction

function! LightlineLinterOK() abort
  let l:counts = ale#statusline#Count(bufnr(''))
  let l:all_errors = l:counts.error + l:counts.style_error
  let l:all_non_errors = l:counts.total - l:all_errors
  return l:counts.total == 0 ? '✓' : ''
endfunction

See :help ale#statusline#Count() and lightline documentation for more information.

5.vi. How can I change the format for echo messages?

There are 3 global options that allow customizing the echoed message.

• g:ale_echo_msg_format where:
  • %s is the error message itself
  • %linter% is the linter name
  • %severity is the severity type
• g:ale_echo_msg_error_str is the string used for error severity.
• g:ale_echo_msg_warning_str is the string used for warning severity.

So for example this:

let g:ale_echo_msg_error_str = 'E'
let g:ale_echo_msg_warning_str = 'W'
let g:ale_echo_msg_format = '[%linter%] %s [%severity%]'

Will give you:

5.vii. How can I execute some code when ALE stops linting?

ALE runs its own autocmd event whenever has a linter has been successfully executed and processed. This autocmd event can be used to call arbitrary functions after ALE stops linting.

augroup YourGroup
    autocmd!
    autocmd User ALELint call YourFunction()
augroup END

5.viii. How can I navigate between errors quickly?

ALE offers some commands with <Plug> keybinds for moving between warnings and errors quickly. You can map the keys Ctrl+j and Ctrl+k to moving between errors for example:

nmap <silent> <C-k> <Plug>(ale_previous_wrap)
nmap <silent> <C-j> <Plug>(ale_next_wrap)

For more information, consult the online documentation with :help ale-navigation-commands.

5.ix. How can I run linters only when I save files?

ALE offers an option g:ale_lint_on_save for enabling running the linters when files are saved. This option is enabled by default. If you only wish to run linters when files are saved, you can turn the other options off.

" Write this in your vimrc file
let g:ale_lint_on_text_changed = 'never'
" You can disable this option too
" if you don't want linters to run on opening a file
let g:ale_lint_on_enter = 0

If for whatever reason you don't wish to run linters again when you save files, you can set g:ale_lint_on_save to 0.

5.x. How can I use the quickfix list instead of the loclist?

The quickfix list can be enabled by turning the g:ale_set_quickfix option on. If you wish to also disable the loclist, you can disable the g:ale_set_loclist option.

" Write this in your vimrc file
let g:ale_set_loclist = 0
let g:ale_set_quickfix = 1

If you wish to show Vim windows for the loclist or quickfix items when a file contains warnings or errors, g:ale_open_list can be set to 1. g:ale_keep_list_window_open can be set to 1 if you wish to keep the window open even after errors disappear.

let g:ale_open_list = 1
" Set this if you want to.
" This can be useful if you are combining ALE with
" some other plugin which sets quickfix errors, etc.
let g:ale_keep_list_window_open = 1

5.xi. How can I check JSX files with both stylelint and eslint?

If you configure ALE options correctly in your vimrc file, and install the right tools, you can check JSX files with stylelint and eslint.

First, install eslint and install stylelint with stylelint-processor-styled-components.

Supposing you have installed both tools correctly, configure your .jsx files so jsx is included in the filetype. You can use an autocmd for this.

augroup FiletypeGroup
    autocmd!
    au BufNewFile,BufRead *.jsx set filetype=javascript.jsx
augroup END

Supposing the filetype has been set correctly, you can set the following options in your vimrc file:

let g:ale_linters = {'jsx': ['stylelint', 'eslint']}
let g:ale_linter_aliases = {'jsx': 'css'}

ALE will alias the jsx filetype so it uses the css filetype linters, and use the original Array of selected linters for jsx from the g:ale_linters object. All available linters will be used for the filetype javascript, and no linter will be run twice for the same file.

5.xii. Will this plugin eat all of my laptop battery power?

ALE takes advantage of the power of various tools to check your code. This of course means that CPU time will be used to continuously check your code. If you are concerned about the CPU time ALE will spend, which will of course imply some cost to battery life, you can adjust your settings to make your CPU do less work.

First, consider increasing the delay before which ALE will run any linters while you type. ALE uses a timeout which is cancelled and reset every time you type, and this delay can be increased so linters are run less often. See :help g:ale_lint_delay for more information.

If you don't wish to run linters while you type, you can disable that behaviour. Set g:ale_lint_on_text_changed to never or normal. You won't get as frequent error checking, but ALE shouldn't block your ability to edit a document after you save a file, so the asynchronous nature of the plugin will still be an advantage.

If you are still concerned, you can turn the automatic linting off altogether, including the option g:ale_lint_on_enter, and you can run ALE manually with :ALELint.