From eda3878a6c121d94f83726ac5ebd059ee0d859ef Mon Sep 17 00:00:00 2001
From: jamestthompson3 <jamestthompson3@gmail.com>
Date: Fri, 6 Jul 2018 21:24:19 +0300
Subject: [PATCH] Add flow-language-server

---
 ale_linters/javascript/flow_ls.vim | 38 ++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)
 create mode 100644 ale_linters/javascript/flow_ls.vim

diff --git a/ale_linters/javascript/flow_ls.vim b/ale_linters/javascript/flow_ls.vim
new file mode 100644
index 00000000..20fc2217
--- /dev/null
+++ b/ale_linters/javascript/flow_ls.vim
@@ -0,0 +1,38 @@
+" Author: t_t <jamestthompson3@gmail.com>
+" Description: Integrate ALE with flow-language-server.
+
+call ale#Set('javascript_flow_ls_executable', 'flow')
+call ale#Set('javascript_flow_ls_use_global',
+\    get(g:, 'ale_use_global_executables', 0)
+\)
+
+function! ale_linters#javascript#flow_ls#GetExecutable(buffer) abort
+    return ale#node#FindExecutable(a:buffer, 'javascript_flow_ls', [
+    \   'node_modules/.bin/flow',
+    \])
+endfunction
+
+function! ale_linters#javascript#flow_ls#GetCommand(buffer) abort
+    let l:executable = ale_linters#javascript#flow_ls#GetExecutable(a:buffer)
+
+    return ale#Escape(l:executable) . ' lsp --from ale-lsp'
+endfunction
+
+function! ale_linters#javascript#flow_ls#FindProjectRoot(buffer) abort
+    let l:flow_config = ale#path#FindNearestFile(a:buffer, '.flowconfig')
+
+    if !empty(l:flow_config)
+        return fnamemodify(l:flow_config, ':h')
+    endif
+
+    return ''
+endfunction
+
+call ale#linter#Define('javascript', {
+\   'name': 'flow-language-server',
+\   'lsp': 'stdio',
+\   'executable_callback': 'ale_linters#javascript#flow_ls#GetExecutable',
+\   'command_callback': 'ale_linters#javascript#flow_ls#GetCommand',
+\   'project_root_callback': 'ale_linters#javascript#flow_ls#FindProjectRoot',
+\   'language': 'javascript',
+\})