selinux-refpolicy/refpolicy/policy/modules/admin/dmesg.if

## <module name="dmesg">
## <summary>Policy for dmesg.</summary>

########################################
## <interface name="dmesg_domtrans">
##	<description>
##		Execute dmesg in the dmesg domain.
##	</description>
##	<parameter name="domain">
##		The type of the process performing this action.
##	</parameter>
## </interface>
#
define(`dmesg_domtrans',`
	gen_require(`
		type dmesg_t, dmesg_exec_t;
		class process sigchld;
		class fd use;
		class fifo_file rw_file_perms;
	')

	corecmd_search_sbin($1)
	domain_auto_trans($1,dmesg_exec_t,dmesg_t)

	allow $1 dmesg_t:fd use;
	allow dmesg_t $1:fd use;
	allow dmesg_t $1:fifo_file rw_file_perms;
	allow dmesg_t $1:process sigchld;
')

########################################
## <interface name="dmesg_exec">
##	<description>
##		Execute dmesg in the caller domain.
##	</description>
##	<parameter name="domain">
##		The type of the process performing this action.
##	</parameter>
## </interface>
#
define(`dmesg_exec',`
	gen_require(`
		type dmesg_exec_t;
	')

	corecmd_search_sbin($1)
	can_exec($1,dmesg_exec_t)
')

## </module>